summaryrefslogtreecommitdiff
path: root/lib/Class/MakeMethods/Standard
diff options
context:
space:
mode:
Diffstat (limited to 'lib/Class/MakeMethods/Standard')
-rw-r--r--lib/Class/MakeMethods/Standard/Array.pm555
-rw-r--r--lib/Class/MakeMethods/Standard/Global.pm405
-rw-r--r--lib/Class/MakeMethods/Standard/Hash.pm501
-rw-r--r--lib/Class/MakeMethods/Standard/Inheritable.pm428
-rw-r--r--lib/Class/MakeMethods/Standard/Universal.pm336
5 files changed, 2225 insertions, 0 deletions
diff --git a/lib/Class/MakeMethods/Standard/Array.pm b/lib/Class/MakeMethods/Standard/Array.pm
new file mode 100644
index 0000000..52c1b0b
--- /dev/null
+++ b/lib/Class/MakeMethods/Standard/Array.pm
@@ -0,0 +1,555 @@
+=head1 NAME
+
+Class::MakeMethods::Standard::Array - Methods for Array objects
+
+=head1 SYNOPSIS
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Array (
+ new => 'new',
+ scalar => [ 'foo', 'bar' ],
+ array => 'my_list',
+ hash => 'my_index',
+ );
+ ...
+
+ my $obj = MyObject->new( foo => 'Foozle' );
+ print $obj->foo();
+
+ $obj->bar('Barbados');
+ print $obj->bar();
+
+ $obj->my_list(0 => 'Foozle', 1 => 'Bang!');
+ print $obj->my_list(1);
+
+ $obj->my_index('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+ print $obj->my_index('foo');
+
+=head1 DESCRIPTION
+
+The Standard::Array suclass of MakeMethods provides a basic
+constructor and accessors for blessed-array object instances.
+
+=head2 Calling Conventions
+
+When you C<use> this package, the method names you provide
+as arguments cause subroutines to be generated and installed in
+your module.
+
+See L<Class::MakeMethods::Standard/"Calling Conventions"> for more information.
+
+=head2 Declaration Syntax
+
+To declare methods, pass in pairs of a method-type name followed
+by one or more method names.
+
+Valid method-type names for this package are listed in L<"METHOD
+GENERATOR TYPES">.
+
+See L<Class::MakeMethods::Standard/"Declaration Syntax"> and L<Class::MakeMethods::Standard/"Parameter Syntax"> for more information.
+
+=cut
+
+package Class::MakeMethods::Standard::Array;
+
+$VERSION = 1.000;
+use strict;
+use Class::MakeMethods::Standard '-isasubclass';
+use Class::MakeMethods::Utility::ArraySplicer 'array_splicer';
+
+########################################################################
+
+=head2 Positional Accessors and %FIELDS
+
+Each accessor method is assigned the next available array index at
+which to store its value.
+
+The mapping between method names and array positions is stored in
+a hash named %FIELDS in the declaring package. When a package
+declares its first positional accessor, its %FIELDS are initialized
+by searching its inheritance tree.
+
+B<Warning>: Subclassing packages that use positional accessors is
+somewhat fragile, since you may end up with two distinct methods assigned to the same position. Specific cases to avoid are:
+
+=over 4
+
+=item *
+
+If you inherit from more than one class with positional accessors,
+the positions used by the two sets of methods will overlap.
+
+=item *
+
+If your superclass adds additional positional accessors after you
+declare your first, they will overlap yours.
+
+=back
+
+=cut
+
+sub _array_index {
+ my $class = shift;
+ my $name = shift;
+ no strict;
+ local $^W = 0;
+ if ( ! scalar %{$class . "::FIELDS"} ) {
+ my @classes = @{$class . "::ISA"};
+ my @fields;
+ while ( @classes ) {
+ my $superclass = shift @classes;
+ if ( scalar %{$superclass . "::FIELDS"} ) {
+ push @fields, %{$superclass . "::FIELDS"};
+ } else {
+ unshift @classes, @{$superclass . "::ISA"}
+ }
+ }
+ %{$class . "::FIELDS"} = @fields
+ }
+ my $field_hash = \%{$class . "::FIELDS"};
+ $field_hash->{$name} or $field_hash->{$name} = scalar keys %$field_hash
+}
+
+########################################################################
+
+=head1 METHOD GENERATOR TYPES
+
+=head2 new - Constructor
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Has a reference to a sample item to copy. This defaults to a reference to an empty array, but you may override this with the C<'defaults' => I<array_ref>> method parameter.
+
+=item *
+
+If called as a class method, makes a new array containing values from the sample item, and blesses it into that class.
+
+=item *
+
+If called on an array-based instance, makes a copy of it and blesses the copy into the same class as the original instance.
+
+=item *
+
+If passed a list of method-value pairs, calls each named method with the associated value as an argument.
+
+=item *
+
+Returns the new instance.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Array (
+ new => 'new',
+ );
+ ...
+
+ # Bare constructor
+ my $empty = MyObject->new();
+
+ # Constructor with initial sequence of method calls
+ my $obj = MyObject->new( foo => 'Foozle', bar => 'Barbados' );
+
+ # Copy with overriding sequence of method calls
+ my $copy = $obj->new( bar => 'Bob' );
+
+=cut
+
+sub new {
+ my $class = shift;
+ map {
+ my $name = $_->{name};
+ my $defaults = $_->{defaults} || [];
+ $name => sub {
+ my $callee = shift;
+ my $self = ref($callee) ? bless( [@$callee], ref($callee) )
+ : bless( [@$defaults], $callee );
+ while ( scalar @_ ) {
+ my $method = shift;
+ $self->$method( shift );
+ }
+ return $self;
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 scalar - Instance Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on an array-based instance.
+
+=item *
+
+Determines the array position associated with the method name, and uses that as an index into each instance to access the related value. This defaults to the next available slot in %FIELDS, but you may override this with the C<'array_index' => I<number>> method parameter, or by pre-filling the contents of %FIELDS.
+
+=item *
+
+If called without any arguments returns the current value (or undef).
+
+=item *
+
+If called with an argument, stores that as the value, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Array (
+ scalar => 'foo',
+ );
+ ...
+
+ # Store value
+ $obj->foo('Foozle');
+
+ # Retrieve value
+ print $obj->foo;
+
+=cut
+
+sub scalar {
+ my $class = shift;
+ map {
+ my $name = $_->{name};
+ my $index = $_->{array_index} ||
+ _array_index( $class->_context('TargetClass'), $name );
+ $name => sub {
+ my $self = shift;
+ if ( scalar @_ ) {
+ $self->[$index] = shift;
+ } else {
+ $self->[$index];
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 array - Instance Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on an array-based instance.
+
+=item *
+
+Determines the array position associated with the method name, and uses that as an index into each instance to access the related value. This defaults to the next available slot in %FIELDS, but you may override this with the C<'array_index' => I<number>> method parameter, or by pre-filling the contents of %FIELDS.
+
+=item *
+
+The value for each instance will be a reference to an array (or undef).
+
+=item *
+
+If called without any arguments, returns the current array-ref value (or undef).
+
+=item *
+
+If called with a single non-ref argument, uses that argument as an index to retrieve from the referenced array, and returns that value (or undef).
+
+=item *
+
+If called with a single array ref argument, uses that list to return a slice of the referenced array.
+
+=item *
+
+If called with a list of argument pairs, each with a non-ref index and an associated value, stores the value at the given index in the referenced array. If the instance's value was previously undefined, a new array is autovivified. The current value in each position will be overwritten, and later arguments with the same index will override earlier ones. Returns the current array-ref value.
+
+=item *
+
+If called with a list of argument pairs, each with the first item being a reference to an array of up to two numbers, loops over each pair and uses those numbers to splice the value array.
+
+The first controlling number is the position at which the splice will begin. Zero will start before the first item in the list. Negative numbers count backwards from the end of the array.
+
+The second number is the number of items to be removed from the list. If it is omitted, or undefined, or zero, no items are removed. If it is a positive integer, that many items will be returned.
+
+If both numbers are omitted, or are both undefined, they default to containing the entire value array.
+
+If the second argument is undef, no values will be inserted; if it is a non-reference value, that one value will be inserted; if it is an array-ref, its values will be copied.
+
+The method returns the items that removed from the array, if any.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Array (
+ array => 'bar',
+ );
+ ...
+
+ # Clear and set contents of list
+ print $obj->bar([ 'Spume', 'Frost' ] );
+
+ # Set values by position
+ $obj->bar(0 => 'Foozle', 1 => 'Bang!');
+
+ # Positions may be overwritten, and in any order
+ $obj->bar(2 => 'And Mash', 1 => 'Blah!');
+
+ # Retrieve value by position
+ print $obj->bar(1);
+
+ # Direct access to referenced array
+ print scalar @{ $obj->bar() };
+
+There are also calling conventions for slice and splice operations:
+
+ # Retrieve slice of values by position
+ print join(', ', $obj->bar( undef, [0, 2] ) );
+
+ # Insert an item at position in the array
+ $obj->bar([3], 'Potatoes' );
+
+ # Remove 1 item from position 3 in the array
+ $obj->bar([3, 1], undef );
+
+ # Set a new value at position 2, and return the old value
+ print $obj->bar([2, 1], 'Froth' );
+
+=cut
+
+sub array {
+ my $class = shift;
+ map {
+ my $name = $_->{name};
+ my $index = $_->{array_index} ||
+ _array_index( $class->_context('TargetClass'), $name );
+ my $init = $_->{auto_init};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ if ( $init and ! defined $self->[$index] ) {
+ $self->[$index] = [];
+ }
+ ( ! $self->[$index] ) ? () :
+ ( wantarray ) ? @{ $self->[$index] } :
+ $self->[$index]
+ } elsif ( scalar(@_) == 1 and ref $_[0] eq 'ARRAY' ) {
+ $self->[$index] = [ @{ $_[0] } ];
+ ( ! $self->[$index] ) ? () :
+ ( wantarray ) ? @{ $self->[$index] } :
+ $self->[$index]
+ } else {
+ $self->[$index] ||= [];
+ array_splicer( $self->[$index], @_ );
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 hash - Instance Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on an array-based instance.
+
+=item *
+
+Determines the array position associated with the method name, and uses that as an index into each instance to access the related value. This defaults to the next available slot in %FIELDS, but you may override this with the C<'array_index' => I<number>> method parameter, or by pre-filling the contents of %FIELDS.
+
+
+=item *
+
+The value for each instance will be a reference to a hash (or undef).
+
+=item *
+
+If called without any arguments, returns the contents of the hash in list context, or a hash reference in scalar context (or undef).
+
+=item *
+
+If called with one argument, uses that argument as an index to retrieve from the referenced hash, and returns that value (or undef). If the single argument is an array ref, then a slice of the referenced hash is returned.
+
+=item *
+
+If called with a list of key-value pairs, stores the value under the given key in the referenced hash. If the instance's value was previously undefined, a new hash is autovivified. The current value under each key will be overwritten, and later arguments with the same key will override earlier ones. Returns the contents of the hash in list context, or a hash reference in scalar context.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Array (
+ hash => 'baz',
+ );
+ ...
+
+ # Set values by key
+ $obj->baz('foo' => 'Foozle', 'bar' => 'Bang!');
+
+ # Values may be overwritten, and in any order
+ $obj->baz('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+
+ # Retrieve value by key
+ print $obj->baz('foo');
+
+ # Retrive slice of values by position
+ print join(', ', $obj->baz( ['foo', 'bar'] ) );
+
+ # Direct access to referenced hash
+ print keys %{ $obj->baz() };
+
+ # Reset the hash contents to empty
+ @{ $obj->baz() } = ();
+
+=cut
+
+sub hash {
+ my $class = shift;
+ map {
+ my $name = $_->{name};
+ my $index = $_->{array_index} ||
+ _array_index( $class->_context('TargetClass'), $name );
+ my $init = $_->{auto_init};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ if ( $init and ! defined $self->[$index] ) {
+ $self->[$index] = {};
+ }
+ ( ! $self->[$index] ) ? () :
+ ( wantarray ) ? %{ $self->[$index] } :
+ $self->[$index]
+ } elsif ( scalar(@_) == 1 ) {
+ if ( ref($_[0]) eq 'HASH' ) {
+ my $hash = shift;
+ $self->[$index] = { %$hash };
+ } elsif ( ref($_[0]) eq 'ARRAY' ) {
+ return @{$self->[$index]}{ @{$_[0]} }
+ } else {
+ return $self->[$index]->{ $_[0] }
+ }
+ } elsif ( scalar(@_) % 2 ) {
+ Carp::croak "Odd number of items in assigment to $name";
+ } else {
+ while ( scalar(@_) ) {
+ my $key = shift();
+ $self->[$index]->{ $key } = shift();
+ }
+ ( wantarray ) ? %{ $self->[$index] } :
+ $self->[$index]
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 object - Instance Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on an array-based instance.
+
+=item *
+
+Determines the array position associated with the method name, and uses that as an index into each instance to access the related value. This defaults to the next available slot in %FIELDS, but you may override this with the C<'array_index' => I<number>> method parameter, or by pre-filling the contents of %FIELDS.
+
+=item *
+
+The value for each instance will be a reference to an object (or undef).
+
+=item *
+
+If called without any arguments returns the current value.
+
+=item *
+
+If called with an argument, stores that as the value, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ object => 'foo',
+ );
+ ...
+
+ # Store value
+ $obj->foo( Foozle->new() );
+
+ # Retrieve value
+ print $obj->foo;
+
+=cut
+
+sub object {
+ my $class = shift;
+ map {
+ my $name = $_->{name};
+ my $index = $_->{array_index} ||
+ _array_index( $class->_context('TargetClass'), $name );
+ my $class = $_->{class};
+ my $init = $_->{auto_init};
+ if ( $init and ! $class ) {
+ Carp::croak("Use of auto_init requires value for class parameter")
+ }
+ my $new_method = $_->{new_method} || 'new';
+ $name => sub {
+ my $self = shift;
+ if ( scalar @_ ) {
+ my $value = shift;
+ if ( $class and ! UNIVERSAL::isa( $value, $class ) ) {
+ Carp::croak "Wrong argument type ('$value') in assigment to $name";
+ }
+ $self->[$index] = $value;
+ } else {
+ if ( $init and ! defined $self->[$index] ) {
+ $self->[$index] = $class->$new_method();
+ } else {
+ $self->[$index];
+ }
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head1 SEE ALSO
+
+See L<Class::MakeMethods> for general information about this distribution.
+
+See L<Class::MakeMethods::Standard> for more about this family of subclasses.
+
+See L<Class::MakeMethods::Standard::Hash> for equivalent functionality
+based on blessed hashes. If your module will be extensively
+subclassed, consider switching to Standard::Hash to avoid the
+subclassing concerns described above.
+
+=cut
+
+1;
diff --git a/lib/Class/MakeMethods/Standard/Global.pm b/lib/Class/MakeMethods/Standard/Global.pm
new file mode 100644
index 0000000..9c1e48d
--- /dev/null
+++ b/lib/Class/MakeMethods/Standard/Global.pm
@@ -0,0 +1,405 @@
+=head1 NAME
+
+Class::MakeMethods::Standard::Global - Global data
+
+=head1 SYNOPSIS
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Global (
+ scalar => [ 'foo' ],
+ array => [ 'my_list' ],
+ hash => [ 'my_index' ],
+ );
+ ...
+
+ MyClass->foo( 'Foozle' );
+ print MyClass->foo();
+
+ print MyClass->new(...)->foo(); # same value for any instance
+ print MySubclass->foo(); # ... and for any subclass
+
+ MyClass->my_list(0 => 'Foozle', 1 => 'Bang!');
+ print MyClass->my_list(1);
+
+ MyClass->my_index('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+ print MyClass->my_index('foo');
+
+
+=head1 DESCRIPTION
+
+The Standard::Global suclass of MakeMethods provides basic accessors for shared data.
+
+=head2 Calling Conventions
+
+When you C<use> this package, the method names you provide
+as arguments cause subroutines to be generated and installed in
+your module.
+
+See L<Class::MakeMethods::Standard/"Calling Conventions"> for more information.
+
+=head2 Declaration Syntax
+
+To declare methods, pass in pairs of a method-type name followed
+by one or more method names.
+
+Valid method-type names for this package are listed in L<"METHOD
+GENERATOR TYPES">.
+
+See L<Class::MakeMethods::Standard/"Declaration Syntax"> and L<Class::MakeMethods::Standard/"Parameter Syntax"> for more information.
+
+=cut
+
+package Class::MakeMethods::Standard::Global;
+
+$VERSION = 1.000;
+use strict;
+use Class::MakeMethods::Standard '-isasubclass';
+use Class::MakeMethods::Utility::ArraySplicer 'array_splicer';
+
+########################################################################
+
+=head1 METHOD GENERATOR TYPES
+
+=head2 scalar - Global Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, and behaves identically regardless of what it was called on.
+
+=item *
+
+If called without any arguments returns the current value.
+
+=item *
+
+If called with an argument, stores that as the value, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Global (
+ scalar => 'foo',
+ );
+ ...
+
+ # Store value
+ MyClass->foo('Foozle');
+
+ # Retrieve value
+ print MyClass->foo;
+
+=cut
+
+sub scalar {
+ map {
+ my $name = $_->{name};
+ my $data;
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ $data;
+ } else {
+ $data = shift;
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 array - Global Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, and behaves identically regardless of what it was called on.
+
+=item *
+
+The global value will be a reference to an array (or undef).
+
+=item *
+
+If called without any arguments, returns the current array-ref value (or undef).
+
+
+=item *
+
+If called with a single non-ref argument, uses that argument as an index to retrieve from the referenced array, and returns that value (or undef).
+
+=item *
+
+If called with a single array ref argument, uses that list to return a slice of the referenced array.
+
+=item *
+
+If called with a list of argument pairs, each with a non-ref index and an associated value, stores the value at the given index in the referenced array. If the global value was previously undefined, a new array is autovivified. The current value in each position will be overwritten, and later arguments with the same index will override earlier ones. Returns the current array-ref value.
+
+=item *
+
+If called with a list of argument pairs, each with the first item being a reference to an array of up to two numbers, loops over each pair and uses those numbers to splice the value array.
+
+The first controlling number is the position at which the splice will begin. Zero will start before the first item in the list. Negative numbers count backwards from the end of the array.
+
+The second number is the number of items to be removed from the list. If it is omitted, or undefined, or zero, no items are removed. If it is a positive integer, that many items will be returned.
+
+If both numbers are omitted, or are both undefined, they default to containing the entire value array.
+
+If the second argument is undef, no values will be inserted; if it is a non-reference value, that one value will be inserted; if it is an array-ref, its values will be copied.
+
+The method returns the items that removed from the array, if any.
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Global (
+ array => 'bar',
+ );
+ ...
+
+ # Clear and set contents of list
+ print MyClass->bar([ 'Spume', 'Frost' ] );
+
+ # Set values by position
+ MyClass->bar(0 => 'Foozle', 1 => 'Bang!');
+
+ # Positions may be overwritten, and in any order
+ MyClass->bar(2 => 'And Mash', 1 => 'Blah!');
+
+ # Retrieve value by position
+ print MyClass->bar(1);
+
+ # Direct access to referenced array
+ print scalar @{ MyClass->bar() };
+
+There are also calling conventions for slice and splice operations:
+
+ # Retrieve slice of values by position
+ print join(', ', MyClass->bar( undef, [0, 2] ) );
+
+ # Insert an item at position in the array
+ MyClass->bar([3], 'Potatoes' );
+
+ # Remove 1 item from position 3 in the array
+ MyClass->bar([3, 1], undef );
+
+ # Set a new value at position 2, and return the old value
+ print MyClass->bar([2, 1], 'Froth' );
+
+=cut
+
+sub array {
+ map {
+ my $name = $_->{name};
+ my $data;
+ my $init = $_->{auto_init};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ if ( $init and ! defined $data ) {
+ $data = [];
+ }
+ ! $data ? () : wantarray ? @$data : $data;
+ } elsif ( scalar(@_) == 1 and ref $_[0] eq 'ARRAY' ) {
+ $data = [ @{ $_[0] } ];
+ wantarray ? @$data : $data;
+ } else {
+ $data ||= [];
+ return array_splicer( $data, @_ );
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 hash - Global Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, and behaves identically regardless of what it was called on.
+
+=item *
+
+The global value will be a reference to a hash (or undef).
+
+=item *
+
+If called without any arguments, returns the contents of the hash in list context, or a hash reference in scalar context (or undef).
+
+=item *
+
+If called with one non-ref argument, uses that argument as an index to retrieve from the referenced hash, and returns that value (or undef).
+
+=item *
+
+If called with one array-ref argument, uses the contents of that array to retrieve a slice of the referenced hash.
+
+=item *
+
+If called with one hash-ref argument, sets the contents of the referenced hash to match that provided.
+
+=item *
+
+If called with a list of key-value pairs, stores the value under the given key in the referenced hash. If the global value was previously undefined, a new hash is autovivified. The current value under each key will be overwritten, and later arguments with the same key will override earlier ones. Returns the contents of the hash in list context, or a hash reference in scalar context.
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Global (
+ hash => 'baz',
+ );
+ ...
+
+ # Set values by key
+ MyClass->baz('foo' => 'Foozle', 'bar' => 'Bang!');
+
+ # Values may be overwritten, and in any order
+ MyClass->baz('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+
+ # Retrieve value by key
+ print MyClass->baz('foo');
+
+ # Retrive slice of values by position
+ print join(', ', MyClass->baz( ['foo', 'bar'] ) );
+
+ # Direct access to referenced hash
+ print keys %{ MyClass->baz() };
+
+ # Reset the hash contents to empty
+ @{ MyClass->baz() } = ();
+
+=cut
+
+sub hash {
+ map {
+ my $name = $_->{name};
+ my $data;
+ my $init = $_->{auto_init};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ if ( $init and ! defined $data ) {
+ $data = {};
+ }
+ ! $data ? () : wantarray ? %$data : $data
+ } elsif ( scalar(@_) == 1 ) {
+ if ( ref($_[0]) eq 'HASH' ) {
+ my $hash = shift;
+ $data = { %$hash };
+ } elsif ( ref($_[0]) eq 'ARRAY' ) {
+ return @{$data}{ @{$_[0]} }
+ } else {
+ return $data->{ $_[0] }
+ }
+ } elsif ( scalar(@_) % 2 ) {
+ Carp::croak "Odd number of items in assigment to $name";
+ } else {
+ while ( scalar(@_) ) {
+ my $key = shift();
+ $data->{ $key } = shift();
+ }
+ wantarray ? %$data : $data;
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 object - Global Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, and behaves identically regardless of what it was called on.
+
+=item *
+
+The global value will be a reference to an object (or undef).
+
+=item *
+
+If called without any arguments returns the current value.
+
+=item *
+
+If called with an argument, stores that as the value, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Global (
+ object => 'foo',
+ );
+ ...
+
+ # Store value
+ MyClass->foo( Foozle->new() );
+
+ # Retrieve value
+ print MyClass->foo;
+
+=cut
+
+sub object {
+ map {
+ my $name = $_->{name};
+ my $data;
+ my $class = $_->{class};
+ my $init = $_->{auto_init};
+ if ( $init and ! $class ) {
+ Carp::croak("Use of auto_init requires value for class parameter")
+ }
+ my $new_method = $_->{new_method} || 'new';
+ $name => sub {
+ my $self = shift;
+ if ( scalar @_ ) {
+ my $value = shift;
+ if ( $class and ! UNIVERSAL::isa( $value, $class ) ) {
+ Carp::croak "Wrong argument type ('$value') in assigment to $name";
+ }
+ $data = $value;
+ } else {
+ if ( $init and ! defined $data ) {
+ $data = $class->$new_method();
+ }
+ $data;
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head1 SEE ALSO
+
+See L<Class::MakeMethods> for general information about this distribution.
+
+See L<Class::MakeMethods::Standard> for more about this family of subclasses.
+
+=cut
+
+1;
diff --git a/lib/Class/MakeMethods/Standard/Hash.pm b/lib/Class/MakeMethods/Standard/Hash.pm
new file mode 100644
index 0000000..ba4f65b
--- /dev/null
+++ b/lib/Class/MakeMethods/Standard/Hash.pm
@@ -0,0 +1,501 @@
+=head1 NAME
+
+Class::MakeMethods::Standard::Hash - Standard hash methods
+
+=head1 SYNOPSIS
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ new => 'new',
+ scalar => [ 'foo', 'bar' ],
+ array => 'my_list',
+ hash => 'my_index',
+ );
+ ...
+
+ my $obj = MyObject->new( foo => 'Foozle' );
+ print $obj->foo();
+
+ $obj->bar('Barbados');
+ print $obj->bar();
+
+ $obj->my_list(0 => 'Foozle', 1 => 'Bang!');
+ print $obj->my_list(1);
+
+ $obj->my_index('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+ print $obj->my_index('foo');
+
+=head1 DESCRIPTION
+
+The Standard::Hash suclass of MakeMethods provides a basic constructor and accessors for blessed-hash object instances.
+
+=head2 Calling Conventions
+
+When you C<use> this package, the method names you provide
+as arguments cause subroutines to be generated and installed in
+your module.
+
+See L<Class::MakeMethods::Standard/"Calling Conventions"> for more information.
+
+=head2 Declaration Syntax
+
+To declare methods, pass in pairs of a method-type name followed
+by one or more method names.
+
+Valid method-type names for this package are listed in L<"METHOD
+GENERATOR TYPES">.
+
+See L<Class::MakeMethods::Standard/"Declaration Syntax"> and L<Class::MakeMethods::Standard/"Parameter Syntax"> for more information.
+
+=cut
+
+package Class::MakeMethods::Standard::Hash;
+
+$VERSION = 1.000;
+use strict;
+use Class::MakeMethods::Standard '-isasubclass';
+use Class::MakeMethods::Utility::ArraySplicer 'array_splicer';
+
+########################################################################
+
+=head1 METHOD GENERATOR TYPES
+
+=head2 new - Constructor
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Has a reference to a sample item to copy. This defaults to a reference to an empty hash, but you may override this with the C<'defaults' => I<hash_ref>> method parameter.
+
+=item *
+
+If called as a class method, makes a new hash and blesses it into that class.
+
+=item *
+
+If called on a hash-based instance, makes a copy of it and blesses the copy into the same class as the original instance.
+
+=item *
+
+If passed a list of key-value pairs, appends them to the new hash. These arguments override any copied values, and later arguments with the same name will override earlier ones.
+
+=item *
+
+Returns the new instance.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ new => 'new',
+ );
+ ...
+
+ # Bare constructor
+ my $empty = MyObject->new();
+
+ # Constructor with initial values
+ my $obj = MyObject->new( foo => 'Foozle', bar => 'Barbados' );
+
+ # Copy with overriding value
+ my $copy = $obj->new( bar => 'Bob' );
+
+=cut
+
+sub new {
+ map {
+ my $name = $_->{name};
+ my $defaults = $_->{defaults} || {};
+ $name => sub {
+ my $callee = shift;
+ my $self = ref($callee) ? bless( { %$callee }, ref $callee )
+ : bless( { %$defaults }, $callee );
+ while ( scalar @_ ) {
+ my $method = shift;
+ UNIVERSAL::can( $self, $method )
+ or Carp::croak("Can't call method '$method' in constructor for " . ( ref($callee) || $callee ));
+ $self->$method( shift );
+ }
+ return $self;
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 scalar - Instance Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on a hash-based instance.
+
+=item *
+
+Has a specific hash key to use to access the related value for each instance.
+This defaults to the method name, but you may override this with the C<'hash_key' => I<string>> method parameter.
+
+=item *
+
+If called without any arguments returns the current value.
+
+=item *
+
+If called with an argument, stores that as the value, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ scalar => 'foo',
+ );
+ ...
+
+ # Store value
+ $obj->foo('Foozle');
+
+ # Retrieve value
+ print $obj->foo;
+
+=cut
+
+sub scalar {
+ map {
+ my $name = $_->{name};
+ my $hash_key = $_->{hash_key} || $_->{name};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ $self->{$hash_key};
+ } else {
+ $self->{$hash_key} = shift;
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 array - Instance Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on a hash-based instance.
+
+=item *
+
+Has a specific hash key to use to access the related value for each instance.
+This defaults to the method name, but you may override this with the C<'hash_key' => I<string>> method parameter.
+
+=item *
+
+The value for each instance will be a reference to an array (or undef).
+
+=item *
+
+If called without any arguments, returns the contents of the array in list context, or an array reference in scalar context (or undef).
+
+=item *
+
+If called with a single array ref argument, sets the contents of the array to match the contents of the provided one.
+
+=item *
+
+If called with a single numeric argument, uses that argument as an index to retrieve from the referenced array, and returns that value (or undef).
+
+=item *
+
+If called with a two arguments, the first undefined and the second an array ref argument, uses that array's contents as a list of indexes to return a slice of the referenced array.
+
+=item *
+
+If called with a list of argument pairs, each with a numeric index and an associated value, stores the value at the given index in the referenced array. If the instance's value was previously undefined, a new array is autovivified. The current value in each position will be overwritten, and later arguments with the same index will override earlier ones. Returns the current array-ref value.
+
+=item *
+
+If called with a list of argument pairs, each with the first item being a reference to an array of up to two numbers, loops over each pair and uses those numbers to splice the value array.
+
+The first controlling number is the position at which the splice will begin. Zero will start before the first item in the list. Negative numbers count backwards from the end of the array.
+
+The second number is the number of items to be removed from the list. If it is omitted, or undefined, or zero, no items are removed. If it is a positive integer, that many items will be returned.
+
+If both numbers are omitted, or are both undefined, they default to containing the entire value array.
+
+If the second argument is undef, no values will be inserted; if it is a non-reference value, that one value will be inserted; if it is an array-ref, its values will be copied.
+
+The method returns the items that removed from the array, if any.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ array => 'bar',
+ );
+ ...
+
+ # Clear and set contents of list
+ print $obj->bar([ 'Spume', 'Frost' ] );
+
+ # Set values by position
+ $obj->bar(0 => 'Foozle', 1 => 'Bang!');
+
+ # Positions may be overwritten, and in any order
+ $obj->bar(2 => 'And Mash', 1 => 'Blah!');
+
+ # Retrieve value by position
+ print $obj->bar(1);
+
+ # Direct access to referenced array
+ print scalar @{ $obj->bar() };
+
+There are also calling conventions for slice and splice operations:
+
+ # Retrieve slice of values by position
+ print join(', ', $obj->bar( undef, [0, 2] ) );
+
+ # Insert an item at position in the array
+ $obj->bar([3], 'Potatoes' );
+
+ # Remove 1 item from position 3 in the array
+ $obj->bar([3, 1], undef );
+
+ # Set a new value at position 2, and return the old value
+ print $obj->bar([2, 1], 'Froth' );
+
+=cut
+
+sub array {
+ map {
+ my $name = $_->{name};
+ my $hash_key = $_->{hash_key} || $_->{name};
+ my $init = $_->{auto_init};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ if ( $init and ! defined $self->{$hash_key} ) {
+ $self->{$hash_key} = [];
+ }
+ ( ! $self->{$hash_key} ) ? () :
+ ( wantarray ) ? @{ $self->{$hash_key} } :
+ $self->{$hash_key}
+ } elsif ( scalar(@_) == 1 and ref $_[0] eq 'ARRAY' ) {
+ $self->{$hash_key} = [ @{ $_[0] } ];
+ ( ! $self->{$hash_key} ) ? () :
+ ( wantarray ) ? @{ $self->{$hash_key} } :
+ $self->{$hash_key}
+ } else {
+ $self->{$hash_key} ||= [];
+ return array_splicer( $self->{$hash_key}, @_ );
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 hash - Instance Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on a hash-based instance.
+
+=item *
+
+Has a specific hash key to use to access the related value for each instance.
+This defaults to the method name, but you may override this with the C<'hash_key' => I<string>> method parameter.
+
+=item *
+
+The value for each instance will be a reference to a hash (or undef).
+
+=item *
+
+If called without any arguments, returns the contents of the hash in list context, or a hash reference in scalar context (or undef).
+
+=item *
+
+If called with one non-ref argument, uses that argument as an index to retrieve from the referenced hash, and returns that value (or undef).
+
+=item *
+
+If called with one array-ref argument, uses the contents of that array to retrieve a slice of the referenced hash.
+
+=item *
+
+If called with one hash-ref argument, sets the contents of the referenced hash to match that provided.
+
+=item *
+
+If called with a list of key-value pairs, stores the value under the given key in the referenced hash. If the instance's value was previously undefined, a new hash is autovivified. The current value under each key will be overwritten, and later arguments with the same key will override earlier ones. Returns the contents of the hash in list context, or a hash reference in scalar context.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ hash => 'baz',
+ );
+ ...
+
+ # Set values by key
+ $obj->baz('foo' => 'Foozle', 'bar' => 'Bang!');
+
+ # Values may be overwritten, and in any order
+ $obj->baz('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+
+ # Retrieve value by key
+ print $obj->baz('foo');
+
+ # Retrive slice of values by position
+ print join(', ', $obj->baz( ['foo', 'bar'] ) );
+
+ # Direct access to referenced hash
+ print keys %{ $obj->baz() };
+
+ # Reset the hash contents to empty
+ %{ $obj->baz() } = ();
+
+=cut
+
+sub hash {
+ map {
+ my $name = $_->{name};
+ my $hash_key = $_->{hash_key} || $_->{name};
+ my $init = $_->{auto_init};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ if ( $init and ! defined $self->{$hash_key} ) {
+ $self->{$hash_key} = {};
+ }
+ ( ! $self->{$hash_key} ) ? () :
+ ( wantarray ) ? %{ $self->{$hash_key} } :
+ $self->{$hash_key}
+ } elsif ( scalar(@_) == 1 ) {
+ if ( ref($_[0]) eq 'HASH' ) {
+ $self->{$hash_key} = { %{$_[0]} };
+ } elsif ( ref($_[0]) eq 'ARRAY' ) {
+ return @{$self->{$hash_key}}{ @{$_[0]} }
+ } else {
+ return $self->{$hash_key}->{ $_[0] }
+ }
+ } elsif ( scalar(@_) % 2 ) {
+ Carp::croak "Odd number of items in assigment to $name";
+ } else {
+ while ( scalar(@_) ) {
+ my $key = shift();
+ $self->{$hash_key}->{ $key } = shift();
+ }
+ return $self->{$hash_key};
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 object - Instance Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Must be called on a hash-based instance.
+
+=item *
+
+Has a specific hash key to use to access the related value for each instance.
+This defaults to the method name, but you may override this with the C<'hash_key' => I<string>> method parameter.
+
+=item *
+
+The value for each instance will be a reference to an object (or undef).
+
+=item *
+
+If called without any arguments returns the current value.
+
+=item *
+
+If called with an argument, stores that as the value, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Hash (
+ object => 'foo',
+ );
+ ...
+
+ # Store value
+ $obj->foo( Foozle->new() );
+
+ # Retrieve value
+ print $obj->foo;
+
+=cut
+
+sub object {
+ map {
+ my $name = $_->{name};
+ my $hash_key = $_->{hash_key} || $_->{name};
+ my $class = $_->{class};
+ my $init = $_->{auto_init};
+ if ( $init and ! $class ) {
+ Carp::croak("Use of auto_init requires value for class parameter")
+ }
+ my $new_method = $_->{new_method} || 'new';
+ $name => sub {
+ my $self = shift;
+ if ( scalar @_ ) {
+ my $value = shift;
+ if ( $class and ! UNIVERSAL::isa( $value, $class ) ) {
+ Carp::croak "Wrong argument type ('$value') in assigment to $name";
+ }
+ $self->{$hash_key} = $value;
+ } else {
+ if ( $init and ! defined $self->{$hash_key} ) {
+ $self->{$hash_key} = $class->$new_method();
+ }
+ $self->{$hash_key};
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head1 SEE ALSO
+
+See L<Class::MakeMethods> for general information about this distribution.
+
+See L<Class::MakeMethods::Standard> for more about this family of subclasses.
+
+=cut
+
+1;
diff --git a/lib/Class/MakeMethods/Standard/Inheritable.pm b/lib/Class/MakeMethods/Standard/Inheritable.pm
new file mode 100644
index 0000000..d1b72ac
--- /dev/null
+++ b/lib/Class/MakeMethods/Standard/Inheritable.pm
@@ -0,0 +1,428 @@
+=head1 NAME
+
+Class::MakeMethods::Standard::Inheritable - Overridable data
+
+=head1 SYNOPSIS
+
+ package MyClass;
+
+ use Class::MakeMethods( 'Standard::Inheritable:scalar' => 'foo' );
+ # We now have an accessor method for an "inheritable" scalar value
+
+ MyClass->foo( 'Foozle' ); # Set a class-wide value
+ print MyClass->foo(); # Retrieve class-wide value
+
+ my $obj = MyClass->new(...);
+ print $obj->foo(); # All instances "inherit" that value...
+
+ $obj->foo( 'Foible' ); # until you set a value for an instance.
+ print $obj->foo(); # This now finds object-specific value.
+ ...
+
+ package MySubClass;
+ @ISA = 'MyClass';
+
+ print MySubClass->foo(); # Intially same as superclass,
+ MySubClass->foo('Foobar'); # but overridable per subclass,
+ print $subclass_obj->foo(); # and shared by its instances
+ $subclass_obj->foo('Fosil');# until you override them...
+ ...
+
+ # Similar behaviour for hashes and arrays is currently incomplete
+ package MyClass;
+ use Class::MakeMethods::Standard::Inheritable (
+ array => 'my_list',
+ hash => 'my_index',
+ );
+
+ MyClass->my_list(0 => 'Foozle', 1 => 'Bang!');
+ print MyClass->my_list(1);
+
+ MyClass->my_index('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+ print MyClass->my_index('foo');
+
+
+=head1 DESCRIPTION
+
+The MakeMethods subclass provides accessor methods that search an inheritance tree to find a value. This allows you to set a shared or default value for a given class, optionally override it in a subclass, and then optionally override it on a per-instance basis.
+
+Note that all MakeMethods methods are inheritable, in the sense that they work as expected for subclasses. These methods are different in that the I<data> accessed by each method can be inherited or overridden in each subclass or instance. See L< Class::MakeMethods::Utility::Inheritable> for more about this type of "inheritable" or overridable" data.
+
+
+=head2 Calling Conventions
+
+When you C<use> this package, the method names you provide
+as arguments cause subroutines to be generated and installed in
+your module.
+
+See L<Class::MakeMethods::Standard/"Calling Conventions"> for more information.
+
+=head2 Declaration Syntax
+
+To declare methods, pass in pairs of a method-type name followed
+by one or more method names.
+
+Valid method-type names for this package are listed in L<"METHOD
+GENERATOR TYPES">.
+
+See L<Class::MakeMethods::Standard/"Declaration Syntax"> and L<Class::MakeMethods::Standard/"Parameter Syntax"> for more information.
+
+=cut
+
+package Class::MakeMethods::Standard::Inheritable;
+
+$VERSION = 1.000;
+use strict;
+
+use Class::MakeMethods::Standard '-isasubclass';
+use Class::MakeMethods::Utility::Inheritable qw(get_vvalue set_vvalue find_vself);
+use Class::MakeMethods::Utility::ArraySplicer 'array_splicer';
+
+########################################################################
+
+=head1 METHOD GENERATOR TYPES
+
+=head2 scalar - Class-specific Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class or instance method, on the declaring class or any subclass.
+
+=item *
+
+If called without any arguments returns the current value for the callee. If the callee has not had a value defined for this method, searches up from instance to class, and from class to superclass, until a callee with a value is located.
+
+=item *
+
+If called with an argument, stores that as the value associated with the callee, whether instance or class, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Inheritable (
+ scalar => 'foo',
+ );
+ ...
+
+ # Store value
+ MyClass->foo('Foozle');
+
+ # Retrieve value
+ print MyClass->foo;
+
+=cut
+
+sub scalar {
+ my $class = shift;
+ map {
+ my $method = $_;
+ my $name = $method->{name};
+ $method->{data} ||= {};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ get_vvalue($method->{data}, $self);
+ } else {
+ my $value = shift;
+ set_vvalue($method->{data}, $self, $value);
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 array - Class-specific Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, Must be called on a hash-based instance.
+
+=item *
+
+The class value will be a reference to an array (or undef).
+
+=item *
+
+If called without any arguments, returns the contents of the array in list context, or an array reference in scalar context (or undef).
+
+=item *
+
+If called with a single array ref argument, sets the contents of the array to match the contents of the provided one.
+
+=item *
+
+If called with a single numeric argument, uses that argument as an index to retrieve from the referenced array, and returns that value (or undef).
+
+=item *
+
+If called with a two arguments, the first undefined and the second an array ref argument, uses that array's contents as a list of indexes to return a slice of the referenced array.
+
+=item *
+
+If called with a list of argument pairs, each with a non-ref index and an associated value, stores the value at the given index in the referenced array. If the class value was previously undefined, a new array is autovivified. The current value in each position will be overwritten, and later arguments with the same index will override earlier ones. Returns the current array-ref value.
+
+=item *
+
+If called with a list of argument pairs, each with the first item being a reference to an array of up to two numbers, loops over each pair and uses those numbers to splice the value array.
+
+The first controlling number is the position at which the splice will begin. Zero will start before the first item in the list. Negative numbers count backwards from the end of the array.
+
+The second number is the number of items to be removed from the list. If it is omitted, or undefined, or zero, no items are removed. If it is a positive integer, that many items will be returned.
+
+If both numbers are omitted, or are both undefined, they default to containing the entire value array.
+
+If the second argument is undef, no values will be inserted; if it is a non-reference value, that one value will be inserted; if it is an array-ref, its values will be copied.
+
+The method returns the items that removed from the array, if any.
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Inheritable (
+ array => 'bar',
+ );
+ ...
+
+ # Clear and set contents of list
+ print MyClass->bar([ 'Spume', 'Frost' ] );
+
+ # Set values by position
+ MyClass->bar(0 => 'Foozle', 1 => 'Bang!');
+
+ # Positions may be overwritten, and in any order
+ MyClass->bar(2 => 'And Mash', 1 => 'Blah!');
+
+ # Retrieve value by position
+ print MyClass->bar(1);
+
+ # Direct access to referenced array
+ print scalar @{ MyClass->bar() };
+
+There are also calling conventions for slice and splice operations:
+
+ # Retrieve slice of values by position
+ print join(', ', MyClass->bar( undef, [0, 2] ) );
+
+ # Insert an item at position in the array
+ MyClass->bar([3], 'Potatoes' );
+
+ # Remove 1 item from position 3 in the array
+ MyClass->bar([3, 1], undef );
+
+ # Set a new value at position 2, and return the old value
+ print MyClass->bar([2, 1], 'Froth' );
+
+=cut
+
+sub array {
+ my $class = shift;
+ map {
+ my $method = $_;
+ my $name = $method->{name};
+ $name => sub {
+ my $self = shift;
+
+ if ( scalar(@_) == 0 ) {
+ my $v_self = find_vself($method->{data}, $self);
+ my $value = $v_self ? $method->{data}{$v_self} : ();
+ if ( $method->{auto_init} and ! $value ) {
+ $value = $method->{data}{$self} = [];
+ }
+ ! $value ? () : wantarray ? @$value : $value;
+
+ } elsif ( scalar(@_) == 1 and ref $_[0] eq 'ARRAY' ) {
+ $method->{data}{$self} = [ @{ $_[0] } ];
+ wantarray ? @{ $method->{data}{$self} } : $method->{data}{$self}
+
+ } else {
+ if ( ! exists $method->{data}{$self} ) {
+ my $v_self = find_vself($method->{data}, $self);
+ $method->{data}{$self} = [ $v_self ? @$v_self : () ];
+ }
+ return array_splicer( $method->{data}{$self}, @_ );
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 hash - Class-specific Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, Must be called on a hash-based instance.
+
+=item *
+
+The class value will be a reference to a hash (or undef).
+
+=item *
+
+If called without any arguments, returns the contents of the hash in list context, or a hash reference in scalar context. If the callee has not had a value defined for this method, searches up from instance to class, and from class to superclass, until a callee with a value is located.
+
+=item *
+
+If called with one non-ref argument, uses that argument as an index to retrieve from the referenced hash, and returns that value (or undef). If the callee has not had a value defined for this method, searches up from instance to class, and from class to superclass, until a callee with a value is located.
+
+=item *
+
+If called with one array-ref argument, uses the contents of that array to retrieve a slice of the referenced hash. If the callee has not had a value defined for this method, searches up from instance to class, and from class to superclass, until a callee with a value is located.
+
+=item *
+
+If called with one hash-ref argument, sets the contents of the referenced hash to match that provided.
+
+=item *
+
+If called with a list of key-value pairs, stores the value under the given key in the hash associated with the callee, whether instance or class. If the callee did not previously have a hash-ref value associated with it, searches up instance to class, and from class to superclass, until a callee with a value is located, and copies that hash before making the assignments. The current value under each key will be overwritten, and later arguments with the same key will override earlier ones. Returns the contents of the hash in list context, or a hash reference in scalar context.
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Inheritable (
+ hash => 'baz',
+ );
+ ...
+
+ # Set values by key
+ MyClass->baz('foo' => 'Foozle', 'bar' => 'Bang!');
+
+ # Values may be overwritten, and in any order
+ MyClass->baz('broccoli' => 'Blah!', 'foo' => 'Fiddle');
+
+ # Retrieve value by key
+ print MyClass->baz('foo');
+
+ # Retrive slice of values by position
+ print join(', ', MyClass->baz( ['foo', 'bar'] ) );
+
+ # Direct access to referenced hash
+ print keys %{ MyClass->baz() };
+
+ # Reset the hash contents to empty
+ @{ MyClass->baz() } = ();
+
+B<NOTE: THIS METHOD GENERATOR IS INCOMPLETE.>
+
+=cut
+
+sub hash {
+ my $class = shift;
+ map {
+ my $method = $_;
+ my $name = $method->{name};
+ $name => sub {
+ my $self = shift;
+ if ( scalar(@_) == 0 ) {
+ my $v_self = find_vself($method->{data}, $self);
+ my $value = $v_self ? $method->{data}{$v_self} : ();
+ if ( $method->{auto_init} and ! $value ) {
+ $value = $method->{data}{$self} = {};
+ }
+ ! $value ? () : wantarray ? %$value : $value;
+ } elsif ( scalar(@_) == 1 ) {
+ if ( ref($_[0]) eq 'HASH' ) {
+ $method->{data}{$self} = { %{$_[0]} };
+ } elsif ( ref($_[0]) eq 'ARRAY' ) {
+ my $v_self = find_vself($method->{data}, $self);
+ return unless $v_self;
+ return @{$method->{data}{$v_self}}{ @{$_[0]} }
+ } else {
+ my $v_self = find_vself($method->{data}, $self);
+ return unless $v_self;
+ return $method->{data}{$v_self}->{ $_[0] };
+ }
+ } elsif ( scalar(@_) % 2 ) {
+ Carp::croak "Odd number of items in assigment to $method->{name}";
+ } else {
+ if ( ! exists $method->{data}{$self} ) {
+ my $v_self = find_vself($method->{data}, $self);
+ $method->{data}{$self} = { $v_self ? %$v_self : () };
+ }
+ while ( scalar(@_) ) {
+ my $key = shift();
+ $method->{data}{$self}->{ $key } = shift();
+ }
+ wantarray ? %{ $method->{data}{$self} } : $method->{data}{$self};
+ }
+ }
+ } $class->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 object - Class-specific Ref Accessor
+
+For each method name passed, uses a closure to generate a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+May be called as a class method, or on any instance or subclass, Must be called on a hash-based instance.
+
+=item *
+
+The class value will be a reference to an object (or undef).
+
+=item *
+
+If called without any arguments returns the current value for the callee. If the callee has not had a value defined for this method, searches up from instance to class, and from class to superclass, until a callee with a value is located.
+
+=item *
+
+If called with an argument, stores that as the value associated with the callee, whether instance or class, and returns it,
+
+=back
+
+Sample declaration and usage:
+
+ package MyClass;
+ use Class::MakeMethods::Standard::Inheritable (
+ object => 'foo',
+ );
+ ...
+
+ # Store value
+ MyClass->foo( Foozle->new() );
+
+ # Retrieve value
+ print MyClass->foo;
+
+B<NOTE: THIS METHOD GENERATOR HAS NOT BEEN WRITTEN YET.>
+
+=cut
+
+sub object { }
+
+########################################################################
+
+=head1 SEE ALSO
+
+See L<Class::MakeMethods> for general information about this distribution.
+
+See L<Class::MakeMethods::Standard> for more about this family of subclasses.
+
+=cut
+
+1;
diff --git a/lib/Class/MakeMethods/Standard/Universal.pm b/lib/Class/MakeMethods/Standard/Universal.pm
new file mode 100644
index 0000000..641b159
--- /dev/null
+++ b/lib/Class/MakeMethods/Standard/Universal.pm
@@ -0,0 +1,336 @@
+=head1 NAME
+
+Class::MakeMethods::Standard::Universal - Generic Methods
+
+
+=head1 SYNOPSIS
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Universal (
+ no_op => 'this',
+ abstract => 'that',
+ delegate => { name=>'play_music', target=>'instrument', method=>'play' },
+ );
+
+
+=head1 DESCRIPTION
+
+The Standard::Universal suclass of MakeMethods provides a [INCOMPLETE].
+
+=head2 Calling Conventions
+
+When you C<use> this package, the method names you provide
+as arguments cause subroutines to be generated and installed in
+your module.
+
+See L<Class::MakeMethods::Standard/"Calling Conventions"> for more information.
+
+=head2 Declaration Syntax
+
+To declare methods, pass in pairs of a method-type name followed
+by one or more method names.
+
+Valid method-type names for this package are listed in L<"METHOD
+GENERATOR TYPES">.
+
+See L<Class::MakeMethods::Standard/"Declaration Syntax"> and L<Class::MakeMethods::Standard/"Parameter Syntax"> for more information.
+
+=cut
+
+package Class::MakeMethods::Standard::Universal;
+
+$VERSION = 1.000;
+use strict;
+use Carp;
+use Class::MakeMethods::Standard '-isasubclass';
+
+########################################################################
+
+=head1 METHOD GENERATOR TYPES
+
+=head2 no_op - Placeholder
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Does nothing.
+
+=back
+
+You might want to create and use such methods to provide hooks for
+subclass activity.
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Universal (
+ no_op => 'whatever',
+ );
+ ...
+
+ # Doesn't do anything
+ MyObject->whatever();
+
+=cut
+
+sub no_op {
+ map {
+ my $method = $_;
+ $method->{name} => sub { }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 abstract - Placeholder
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Fails with an error message.
+
+=back
+
+This is intended to support the use of abstract methods, that must
+be overidden in a useful subclass.
+
+If each subclass is expected to provide an implementation of a given method, using this abstract method will replace the generic error message below with the clearer, more explicit error message that follows it:
+
+ Can't locate object method "foo" via package "My::Subclass"
+ The "foo" method is abstract and can not be called on My::Subclass
+
+However, note that the existence of this method will be detected by UNIVERSAL::can(), so it is not suitable for use in optional interfaces, for which you may wish to be able to detect whether the method is supported or not.
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Universal (
+ abstract => 'whatever',
+ );
+ ...
+
+ package MySubclass;
+ sub whatever { ... }
+
+ # Failure
+ MyObject->whatever();
+
+ # Success
+ MySubclass->whatever();
+
+=cut
+
+sub abstract {
+ map {
+ my $method = $_;
+ $method->{name} => sub {
+ my $self = shift;
+ my $class = ref($self) ? "a " . ref($self) . " object" : $self;
+ croak("The $method->{name} method is abstract and can not be called on $class");
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 call_methods - Call methods by name
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Accepts a hash of key-value pairs, or a reference to hash of such pairs. For each pair, the key is interpreted as the name of a method to call, and the value is the argument to be passed to that method.
+
+=back
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Universal (
+ call_methods => 'init',
+ );
+ ...
+
+ my $object = MyObject->new()
+ $object->init( foo => 'Foozle', bar => 'Barbados' );
+
+ # Equivalent to:
+ $object->foo('Foozle');
+ $object->bar('Barbados');
+
+=cut
+
+sub call_methods {
+ map {
+ my $method = $_;
+ $method->{name} => sub {
+ my $self = shift;
+ local @_ = %{$_[0]} if ( scalar @_ == 1 and ref($_[0]) eq 'HASH');
+ while (scalar @_) {
+ my $key = shift;
+ $self->$key( shift )
+ }
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+
+########################################################################
+
+=head2 join_methods - Concatenate results of other methods
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Has a list of other methods names as an arrayref in the 'methods' parameter. B<Required>.
+
+=item *
+
+When called, calls each of the named method on itself, in order, and returns the concatenation of their results.
+
+=item *
+
+If a 'join' parameter is provided it is included between each method result.
+
+=item *
+
+If the 'skip_blanks' parameter is omitted, or is provided with a true value, removes all undefined or empty-string values from the results.
+
+=back
+
+=cut
+
+sub join_methods {
+ map {
+ my $method = $_;
+ $method->{methods} or confess;
+ $method->{join} = '' if ( ! defined $method->{join} );
+ $method->{skip_blanks} = '1' if ( ! defined $method->{skip_blanks} );
+ $method->{name} => sub {
+ my $self = shift;
+ my $joiner = $method->{join};
+ my @values = map { $self->$_() } @{ $method->{methods} };
+ @values = grep { defined and length } @values if ( $method->{skip_blanks} );
+ join $joiner, @values;
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 alias - Call another method
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Calls another method on the same callee.
+
+=back
+
+You might create such a method to extend or adapt your class' interface.
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Universal (
+ alias => { name=>'click_here', target=>'complex_machinery' }
+ );
+ sub complex_machinery { ... }
+ ...
+
+ $myobj->click_here(...); # calls $myobj->complex_machinery(...)
+
+=cut
+
+sub alias {
+ map {
+ my $method = $_;
+ $method->{name} => sub {
+ my $self = shift;
+
+ my $t_method = $method->{target} or confess("no target");
+ my @t_args = $method->{target_args} ? @{$method->{target_args}} : ();
+
+ $self->$t_method(@t_args, @_);
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head2 delegate - Use another object to provide method
+
+For each method name passed, returns a subroutine with the following characteristics:
+
+=over 4
+
+=item *
+
+Calls a method on self to retrieve another object, and then calls a method on that object and returns its value.
+
+=back
+
+You might want to create and use such methods to faciliate composition of objects from smaller objects.
+
+Sample declaration and usage:
+
+ package MyObject;
+ use Class::MakeMethods::Standard::Universal (
+ 'Standard::Hash:object' => { name=>'instrument' },
+ delegate => { name=>'play_music', target=>'instrument', method=>'play' }
+ );
+ ...
+
+ my $object = MyObject->new();
+ $object->instrument( MyInstrument->new );
+ $object->play_music;
+
+=cut
+
+sub delegate {
+ map {
+ my $method = $_;
+ $method->{method} ||= $method->{name};
+ $method->{name} => sub {
+ my $self = shift;
+
+ my $t_method = $method->{target} or confess("no target");
+ my @t_args = $method->{target_args} ? @{$method->{target_args}} : ();
+
+ my $m_method = $method->{method} or confess("no method");
+ my @m_args = $method->{method_args} ? @{$method->{method_args}} : ();
+ push @m_args, $self if ( $method->{target_args_self} );
+
+ my $obj = $self->$t_method( @t_args )
+ or croak("Can't delegate $method->{name} because $t_method is empty");
+
+ $obj->$m_method(@m_args, @_);
+ }
+ } (shift)->_get_declarations(@_)
+}
+
+########################################################################
+
+=head1 SEE ALSO
+
+See L<Class::MakeMethods> for general information about this distribution.
+
+See L<Class::MakeMethods::Standard> for more about this family of subclasses.
+
+=cut
+
+1;
generated by cgit v1.2.3 (git 2.25.1) at 2026-03-04 18:22:55 +0000